Re: Help: Oracle Websever Checkbox readout

From: Thomas Kyte <tkyte_at_us.oracle.com>
Date: 1998/02/26
Message-ID: <34f7cfd6.22748250@192.86.155.100>#1/1

A copy of this was sent to Wilco Oosterom <cypr081_at_worldonline.nl> (if that email address didn't require changing) On Thu, 26 Feb 1998 20:15:08 +0100, you wrote:

>Can anyone help me with Oracle Webserver readout of checkboxes?
>I manage to work with radiobuttons and dropdownlists but I can't find
>the method for reading all values of a multiple checkbox group.
>
>
>Thanks for replying
>Wilco Oosterom
>cypr081_at_worldonline.nl

you would use pl/sql tables. Here is an example. if you run BAR it will generate a form with 5 checkboxes, all with the same name. It calls FOO and FOO prints out the checkboxes you picked. I have 2 implementations of FOO, one for 7.2 and less and the other for 7.3 and up.

create or replace package types
as

    type checkBoxArray is table of varchar2(25) index by binary_integer;

    emptyCBArray checkBoxArray;
end;
/

create or replace procedure bar
as
begin

    htp.formOpen( 'foo' );

    htp.p( 'Select Some Stuff<br>' );

    for i in 1 .. 5 loop

        htp.formCheckBox( 'p_checkboxes', 'Checkbox ' || i );
        htp.p( ' A checkbox<br>' );

    end loop;
    htp.formSubmit;
    htp.formClose;
end;
/

create or replace procedure foo
( p_checkboxes in types.checkBoxArray default types.emptyCBArray ) is
begin

    htp.p( 'Here is what you picked:<br>' );     for i in 1 .. 100000 loop
    begin

        htp.p( 'You checked ' || p_checkboxes(i) || '<br>' );     exception

        when no_data_found then EXIT;
    end;
    end loop;
end;
/

• ALTERNATE way to code foo in version 7.3 and up:

create or replace procedure foo
( p_checkboxes in types.checkBoxArray default types.emptyCBArray ) is
begin

    htp.p( 'Here is what you picked:<br>' );

    for i in 1 .. p_checkboxes.count loop

        htp.p( 'You checked ' || p_checkboxes(i) || '<br>' );     end loop;
end;
/  

Thomas Kyte
tkyte_at_us.oracle.com
Oracle Government
Bethesda MD  

http://govt.us.oracle.com/ -- downloadable utilities  

---

Opinions are mine and do not necessarily reflect those of Oracle Corporation  

Anti-Anti Spam Msg: if you want an answer emailed to you, you have to make it easy to get email to you. Any bounced email will be treated the same way i treat SPAM-- I delete it. Received on Thu Feb 26 1998 - 00:00:00 CST