PROCEDURE activity_to_spawn_subprocesses (
    itemtype        IN  VARCHAR2
,   itemkey         IN  VARCHAR2
,   actid           IN  NUMBER
,   funcmode        IN  VARCHAR2
,   resultout       OUT VARCHAR2
)
IS
    l_subprocess_itemtype       applsys.wf_item_types.name%TYPE;
    l_subprocess_itemkey        applsys.wf_items.item_key%TYPE;
    l_subprocess_process_name   applsys.wf_activities.name%TYPE;
BEGIN
    IF (funcmode = apps.wf_engine.eng_run) THEN

        -- l_subprocess_itemtype is the item type where your subprocess
        -- lives.
        l_subprocess_itemtype       := 'XXDETAIL';

        -- l_subprocess_process_name is the internal name of the process
        -- you are going to be calling for each individual on your CC list.
        l_subprocess_process_name   := 'PROCESS_EMAIL_CCLIST_MEMBER';

        FOR cur IN (SELECT email_address FROM cc_list)
        LOOP
            -- For your subprocess, you need to generate an itemkey.
            -- Since an item key has to be unique for any given item
            -- type, this subprocess item key should probably be
            -- derived from your E-mail address or some other primary
            -- key somehow.  Note, I've provided no code for this
            -- generate_item_key_from_email function.  That's up
            -- to you.
            l_subprocess_itemkey := generate_item_key_from_email (
                                        cur.email_address);

            -- Now you need to call this "create process" procedure.
            apps.wf_engine.createprocess (
                itemtype => l_subprocess_itemtype
            ,   itemkey  => l_subprocess_itemkey
            ,   process  => l_subprocess_process_name);

            -- Here, you define the master/detail relationship between
            -- your item types/item keys.
            apps.wf_engine.setitemparent (
                itemtype        => l_subprocess_itemtype
            ,   itemkey         => l_subprocess_itemkey
            ,   parent_itemtype => itemtype -- from this proc's input parameter
            ,   parent_itemkey  => itemkey  -- from this proc's input parameter
            ,   parent_context  => NULL);

            -- This procedure call actually kicks off the process.
            apps.wf_engine.startprocess (
                itemtype    => l_subprocess_itemtype
            ,   itemkey     => l_subprocess_itemkey);
        END LOOP;

    END IF;

END activity_to_spawn_subprocesses;