PROCEDURE r4_export_to_excel
IS
-- Declare handles to OLE objects
   application     client_ole2.obj_type;
   workbooks       client_ole2.obj_type;
   workbook        client_ole2.obj_type;
   worksheets      client_ole2.obj_type;
   worksheet       client_ole2.obj_type;
   v_path          VARCHAR2 (1000);
   -- Declare handles to OLE argument lists
   args            client_ole2.list_type;
   i               NUMBER                := 1;

   CURSOR cp
   IS
      SELECT irdf_filter_value
        FROM inv_rpt_data_filter
       WHERE irdf_org_code = :parameter.global_orgcode
         AND irdf_form_id = :parameter.irdf_form_id
         AND irdf_filter_type = 'PROJECT'
         AND irdf_login_user = :parameter.v_sess_id;
BEGIN
   v_path := 'D:\Project_MIS_R4.xlsx';
   :parameter.v_sess_id := get_session_data ('SESSIONID');
   --Creating new excel
   application := client_ole2.create_obj ('Excel.Application');
   client_ole2.set_property (application, 'Visible', 1);
   workbooks := client_ole2.get_obj_property (application, 'Workbooks');
   --Setting path
   args := client_ole2.create_arglist;
   client_ole2.add_arg (args, v_path);
   workbook := client_ole2.get_obj_property (workbooks, 'Open', args);
   client_ole2.destroy_arglist (args);

   FOR j IN cp                     --For loop added for each multiple project
   LOOP
      i := i + 1;
      :parameter.v_proj := j.irdf_filter_value;
      worksheets := client_ole2.get_obj_property (workbook, 'Worksheets');
      worksheet := client_ole2.get_obj_property (application, 'activesheet');
      --Code newly added for new sheet
      args := client_ole2.create_arglist;
      client_ole2.add_arg (args, i);           -- i represents the sheet no..
      worksheet := client_ole2.get_obj_property (worksheets, 'Item', args);
      client_ole2.set_property (worksheet, 'Name', j.irdf_filter_value);
      --Naming sheets
      client_ole2.destroy_arglist (args);
      proj_mis_costover_rpt_proc_r4 (:GLOBAL.orgcode,
                                     :parameter.v_proj,
                                     :rep_mon,
                                     :fin_year,
                                     :parameter.v_sess_id,
                                     'MCO'
                                    );
      r4_mis_bud_act_forecast_pl (worksheet);
                   /* Budget, Actual & Forecast Details of each budget head */
      r4_mis_aging_details (worksheet);        /* Aging & Retention Details */
      -- Enable user to view the Excel application to see results.
      client_ole2.set_property (application, 'Visible', 'True');
-- Release all OLE object handles
      client_ole2.RELEASE_OBJ (worksheet);
      client_ole2.RELEASE_OBJ (worksheets);
   END LOOP;

   client_ole2.RELEASE_OBJ (workbook);
   client_ole2.RELEASE_OBJ (workbooks);
   client_ole2.RELEASE_OBJ (application);
END;